perm filename SYSINI[KA,SYS] blob
sn#227160 filedate 1976-07-24 generic text, type C, neo UTF8
COMMENT ⊗ VALID 00009 PAGES
C REC PAGE DESCRIPTION
C00001 00001
C00002 00002 BEGIN SYSINI ↔ SUBTTL INITIALIZE SYSTEM DATA STORAGE
C00012 00003 FALLS THROUGH
C00015 00004 IOGO - INITIALIZE ALL IODEVICES
C00022 00005 NORMALIZE ALL JOB SLOTS.
C00024 00006 MOVEI TAC,[ASCIZ /SYSTEM STARTED ON /]
C00026 00007 SYIDDT - INITIALIZE SWAPPING/XCOR DDT.
C00029 00008 P2 INITIALIZE ROUTINE
C00032 00009 POWER DOWN ROUTINES
C00034 ENDMK
C⊗;
BEGIN SYSINI ↔ SUBTTL INITIALIZE SYSTEM DATA STORAGE
;200 RESTART CODE HAS BEEN FLUSHED. IT HASN'T WORKED RIGHT FOR ABOUT 4 YEARS
;AND IT'S TOO HORRIBLE TO ATTEMPT TO FIX IT, CONSIDERING THE PROLIFERATION
;OF IMPORTANT DATA STRUCTURES LOCATED IN FREE STORAGE. (MOST PARTICULARLY
;JBTMAP, AND EVENTUALLY, SWAPPING INFORMATION)
;200 RESTART WILL ATTEMPT TO REINITIALIZE EVERYTHING
↑SYSINI:JSP TAC,.+1 ;HERE FOR STARTING VIRGIN SYSTEM AT 200
TLNE TAC,10000 ;USER MODE?
JRST START ;YES. SOMEONE IS RUNNING THE DMP COPY.
CONO APR,200000 ;I/O RESET AGAIN.
CONO PI,10400 ;CLEAR PI SYSTEM
IFKL10,< ;ASSMBLE FOR KL10 BASED SYSTEMS
DATAO KLPAG,[400100,,0] ;START OUT WITH SOME DECENT ACS
CONSZ APR,SWEEPB ;WAIT FOR SWEEP BUSY TO FALL
JRST .-1
CONSO KLPAG,600000 ;IS THE CACHE ON ALREADY?
JRST SYS.I1 ;NO.
BLKO CCA, ;VALIDATE CORE
CONSZ APR,SWEEPB
JRST .-1
SYS.I1: CONO KLPAG,KLEPT⊗-9 ;TURN OFF CACHE. SET EPT. TURN OFF MAP
DATAI CCA,0 ;SWEEP CACHE. INVALIDATE ALL.
CONSZ APR,SWEEPB ;WAIT FOR SWEEP BUSY TO FALL
JRST .-1
DATAO KLPAG,[100000,,400000+KLUPT⊗-9] ;SET UPT
MOVEI TAC,60000+KLEPT⊗-9
MOVEM TAC,KLPCON ;SAVE AS USUAL KLPAG CONO
>;IFKL10
XCT ONCEI ;DO ONCE-ONLY DIALOGUE
MOVE P,[-ERRPLN,,ERRPDL-1] ;INITIALIZE DDT ONCE ONLY!
IFN FTDDT,<
PUSHJ P,SYIDDT
MOVEI TAC,SYSIN0 ;200 RESTARTS TO SYSIN0
HRRM TAC,SYSDSP
HRRM TAC,SYSDSP+3
>;FTDDT
IFKL10,<
MOVEI TAC,405 ;READ KL10 CLOCK DEFAULT WORD
PUSHJ P,DTEXX
LDB TAC,[POINT 4,TAC,3] ;GET THE CACHE ENABLES
TRO TAC,600000
TRZE TAC,17 ;SKIP IF NO CACHES ENABLED
IORM TAC,KLPCON ;INCLUDE CACHE LOOK AND LOAD IN KLPAG CONO
BLKI KLPAG,[ EXPGT⊗-9 ;SET UP PAGE TABLE POINTERS
400000,,0 ]
>;IFKL10
IFN FTHSYS,<
;HERE, ONCE ONLY, WE BLT THE SYSTEM HIGH SEGMENT INTO HICORE.
;DDT INITIALIZATION SETS FHIPAG.
NOKL10,<
MOVE TAC,[JSR INITRP]
MOVEM TAC,170
MOVE TAC,[700000,,PSB⊗-9]
HRRZM TAC,P2PAG
HLLZM TAC,P2PAG1
MOVSI TAC,160040
HRR TAC,FHIPAG ;FIRST PAGE NUMBER OF DESTINATION
MOVE TAC1,[400000,,DDTEXP⊗9] ;INITIAL BLT POINTER
MOVEI AC2,0+(HIEND-400000)⊗-=9
CONO PAG,0 ;LOAD MBR
CONO PAG,7 ;TURN ON MAPPING
;THE FOLLOWING CODE COPIES 400000 TO FHIPAG FF.
HIMOV: CONO PAG,1 ;CLEAR ARS MAPPING EXEC PAGES
MOVEM TAC,EXPGT+DDTEXP ;CLOBBER MAP FOR PAGE DDTPG TO HIGH CORE
MOVE AC1,TAC1 ;GET BLT POINTER
BLT AC1,DDTEXP⊗9+777 ;MOVE PAGE OF SYSTEM INTO PAGE DDTPG
ADD TAC1,[1000,,] ;UPDATE SOURCE OF BLT (DEST. IS DDTEXP⊗9+777)
ADDI TAC,1 ;UPDATE PAGE TABLE POINTER TO HIGH CORE
SOJG AC2,HIMOV ;LOOP, COUNTING DOWN PAGES MOVED.
AOS TAC,EXPGT+DDTEXP
SETZM EXPGT+DDTEXP
HRRZM TAC,FHUPAG ;SAVE PAGE NUMBER OF "FIRST HIGH USER PAGE"
>;NOKL10
IFKL10,<
MOVEI TAC,INITRP
MOVEM TAC,KLUPT+KLPFNP ;NEW PC WORD FOR PAGE FAULTS
MOVSI TAC,160040
HRR TAC,FHIPAG ;FIRST PAGE NUMBER OF DESTINATION
MOVE TAC1,[400000,,DDTEXP⊗9] ;INITIAL BLT POINTER
MOVEI AC2,0+(HIEND-400000)⊗-=9
;THE FOLLOWING CODE COPIES 400000 TO FHIPAG FF.
HIMOV: CONO KLPAG,@KLPCON ;CLEAR ARS MAPPING EXEC PAGES
MOVEM TAC,EXPGT+DDTEXP ;CLOBBER MAP FOR PAGE DDTPG TO HIGH CORE
MOVE AC1,TAC1 ;GET BLT POINTER
BLT AC1,DDTEXP⊗9+777 ;MOVE PAGE OF SYSTEM INTO PAGE DDTPG
ADD TAC1,[1000,,] ;UPDATE SOURCE OF BLT (DEST. IS DDTEXP⊗9+777)
ADDI TAC,1 ;UPDATE PAGE TABLE POINTER TO HIGH CORE
SOJG AC2,HIMOV ;LOOP, COUNTING DOWN PAGES MOVED.
AOS TAC,EXPGT+DDTEXP
SETZM EXPGT+DDTEXP
HRRZM TAC,FHUPAG ;SAVE PAGE NUMBER OF "FIRST HIGH USER PAGE"
CONO KLPAG,KLEPT⊗-9 ;TURN THE MAP OFF NOW!
>;IFKL10
>;FTHSYS
SYSIN0: CONO APR,200000 ;I/O RESET (200 RESTART, IF POSSIBLE?)
CONO PI,10400 ;PI RESET
IFKL10,<
DATAO KLPAG,[400100,,0] ;START OUT WITH SOME DECENT ACS
CONSZ APR,SWEEPB ;WAIT FOR SWEEP BUSY TO FALL
JRST .-1
CONSO KLPAG,600000 ;IS THE CACHE ON ALREADY?
JRST SYS.J1 ;NO.
BLKO CCA, ;VALIDATE CORE
CONSZ APR,SWEEPB
JRST .-1
SYS.J1: CONO KLPAG,KLEPT⊗-9 ;TURN OFF CACHE, MAP.
DATAI CCA,0 ;SWEEP CACHE. INVALIDATE ALL.
CONSZ APR,SWEEPB ;WAIT FOR SWEEP BUSY TO FALL
JRST .-1
>;IFKL10
MOVE P,[-ERRPLN,,ERRPDL-1]
MOVE TAC,SYSSIZ ;SYSTEM SIZE (SET BY DDT INITIALIZATION)
PRINTX SOMEDAY, THESE COULD BE 777
ADDI TAC,1777
TRZ TAC,1777
MOVEM TAC,SYSTOP ;AND SAVE IT (FOR PAGINI)
LSH TAC,-=9
MOVEM TAC,FUPAG ;FIRST USER PAGE.
IFN FTEXPG,<
PUSHJ P,PAGINI
NOKL10,<
MOVE TAC,[700000,,PSB⊗-9]
HRRZM TAC,P2PAG
HLLZM TAC,P2PAG1
CONO PAG,0
CONO PAG,7
>;NOKL10
IFKL10,<
BLKI KLPAG,[ EXPGT⊗-9 ;SET UP PAGE TABLE POINTERS
400000,,0 ]
MOVE TAC,[PCU,,KLPFTR] ;PAGE FAIL TRAP HANDLER
MOVEM TAC,KLUPT+KLPFNP
CONO KLPAG,@KLPCON ;TURN ON MAPPING
DATAO KLPAG,[100000,,400000+KLUPT⊗-9] ;SET UPT
>;IFKL10
JRST SINI0A
>;FTEXPG
HISYS
SINI0A:
SETZM SYSBEG ;ZERO SYSTEM STORAGE
MOVE TAC,[SYSBEG,,SYSBEG+1]
BLT TAC,SYSEND ;CLEAR IT
SETZM STBEG
MOVE TAC,[STBEG,,STBEG+1]
BLT TAC,STEND
SETZM UPTIME
SETZM DPYMAP
MOVE TAC,[DPYMAP,,DPYMAP+1]
BLT TAC,DPYMAP+JOBN-1
SETZM JBTSWP
MOVE TAC,[JBTSWP,,JBTSWP+1]
BLT TAC,JBTSWP+JOBN-1
SETZM JB2SWP
MOVE TAC,[JB2SWP,,JB2SWP+1]
BLT TAC,JB2SWP+JOBN-1
NOKL10,< DATAI APR,TAC ;READ THE DATA SWITCHES >;NOKL10
IFKL10,< PUSHJ P,RSWITCH ;SWITCHES AS STORED BY 11 >;IFKL10
TLC TAC,777
TLNE TAC,-1 ;DO WE HAVE TO TAKE THESE SERIOUSLY?
JRST SYSIN2 ;NO
TRNE TAC,1 ;DOES HE WANT DDT NOW?
PUSHJ P,DDTCAL ;YES GET IT FOR HIM.
MOVSI TAC1,-NMCELS
SYSIN1: SKIPGE MCELTB(TAC1) ;SKIP IF NORMAL SENSE
TRC TAC,400000 ;INVERSE SENSE. COMPLEMENT THE BIT
TRNN TAC,400000 ;SKIP IF WE'RE SETTING.
SETZM @MCELTB(TAC1) ;¬ SETTING: CLEAR THE CELL
TRNE TAC,400000 ;SKIP IF ¬ SETTING
SETOM @MCELTB(TAC1) ;SET THE CELL
ROT TAC,1 ;SHIFT TO INSPECT MORE BITS
AOBJN TAC1,SYSIN1 ;LOOP
IFN FTSWPC,< SKIPE SWPCH2
SETOM SWPCHK >;FTSWPC
SYSIN2: PUSHJ P,CORINI ;INITIALIZE CORE TABLES
MOVEI TAC,[ASCIZ /SYSTEM INITIALIZED ON /]
SKIPN INIMES ;JUST LOADED?
MOVEM TAC,INIMES ;NO. STORE MESSAGE.
;FALLS THROUGH
;FALLS THROUGH
MOVE TAC,[DVDIRIN+TTYATC,,ASSCON+ASSPRG]
HLRZ DDB,DEVLST ;SCAN ALL DEVICES
SYS1: ANDCAM TAC,DEVMOD(DDB) ;CLEAR DEVICE BITS
;DIRECTORY IN CORE, ASSIGNED BY CONSOLE, PROGRAM
SETZM DEVLOG(DDB) ;CLEAR LOGICAL NAME
HLRZ DDB,DEVSER(DDB) ;LINK ONWARDS
JUMPN DDB,SYS1
;FLUSH 200 RESTART ATTEMPTS REG 9/12/75
; MOVEI TAC,IOGO ;GET ADDRESS FOR 200 RESTART
; HRRM TAC,SYSDSP ;STUFF IT IN SYSDSP (200)
MOVEI TAC,P2INI ; CRANK UP P2. IT IS WAITING FOR US
HRRM TAC,P2XFR ; ALLOW P2 TO CONTINUE
; HERE WE MUST DETACH AD AND XGP FROM THE SYSTEM IF P2
; IS NOT ON LINE. THE ONCE ONLY CODE SETS THE FLAG 'DETFLG'
SKIPN DETFLG ; DO WE HAVE TO DETACH?
JRST IOGO ; NO, PROCEED WITH SYSINI
MOVEI TAC,ASSCON ;YES, GET THE 'ASSIGN' BIT
IFG ADNUM,<
IORM TAC,ADDDB+DEVMOD ;OR INTO DEVICE DATA BLOCK
MOVEI DDB,ADDDB ;GET ADDRESS OF DDB FOR PJOBN'S SAKE
DPB TAC,PJOBN ;MAKE SURE THEY ARE ASSIGNED TO JOB 0
>
IFKL10,< ;NO PTP/PTR ON KL10
IORM TAC,PTRDDB+DEVMOD
MOVEI DDB,PTRDDB
DPB TAC,PJOBN
IORM TAC,PTPDDB+DEVMOD
MOVEI DDB,PTPDDB
DPB TAC,PJOBN
>;IFKL10
IORM TAC,XGPDDB+DEVMOD
MOVEI DDB,XGPDDB
DPB TAC,PJOBN
IFG PLTNUM,<
IORM TAC,PLTDDB+DEVMOD
MOVEI DDB,PLTDDB
DPB TAC,PJOBN
>;IFG PLTNUM
IORM TAC,ADCDDB+DEVMOD
MOVEI DDB,ADCDDB
DPB TAC,PJOBN
IORM TAC,DACDDB+DEVMOD
MOVEI DDB,DACDDB
DPB TAC,PJOBN
JRST IOGO ;JUMP TO LOSYS
;IOGO - INITIALIZE ALL IODEVICES
LOSYS
IOGO: MOVE P,[IOWD ERRPLN,ERRPDL]
NOKL10,<
CONO APR,733550+APRCHN ;RESET, CLEAR FLAGS, ENABLE CLOCK INT
CONO PI,11577 ;CLEAR PI SYSTEM
PUSHJ P,FMCHK ;ARE WE USING FAST MEMORY?
JRST IOGO ;NO. LET'S TRY THAT ALL AGAIN
CONO PAG,0
CONO PAG,7
>;NOKL10
IFKL10,< ;ASSEMBLE FOR KL10
CONO APR,700000+APRCHN ;APR RESET (IO RESET)
CONO PI,31577 ;CLEAR PI SYSTEM. (DROP PROGRAM REQUESTS)
DATAO KLPAG,[700000,,400000+KLUPT⊗-=9]
CONO KLPAG,@KLPCON
PUSHJ P,DTEINI
SYNINI CSHCSC
>;IFKL10
JRST IOGO1
HISYS
IOGO1: MOVE AC1,TIME+P1PID ;GET THE CURRENT TIME
MOVE AC2,THSDAT+P1PID ;AND THE DATE
MOVE TAC,[XWD P1DATA,P1DATA+1]
SETZM P1DATA ;ZERO DATA AREA FOR P1
BLT TAC,P1DATA+PDATALEN-1 ;
SETZM RTIME
SETZM TTIME ;CLEAR NULL TIME TOO.
SETZM LASTDISASTER ;AND LAST DISASTER TIME
MOVEM AC1,TIME+P1PID ;RESTORE THE TIME
MOVEM AC1,TIME+P2PID ;SAVE FOR BOTH PROCESSORS
MOVEM AC2,THSDAT+P1PID ;SAVE THE DATE TOO
MOVEM AC2,THSDAT+P2PID ;
IDIVI AC1,JIFSEC ;CONVERT TIME TO SECONDS
HRL AC1,THSDAT ;PUT DATE IN LEFT HALF OF AC1
MOVEM AC1,TIMDAT ;AND SAVE <DATE>,,<TIME IN SECS>
SKIPE INIMES ;SKIP IF THIS IS A RESTART
MOVEM AC1,INITIM ;SAVE TIME OF (RELOAD OR 203 RESTART).
IFN FTBAT,<
MOVEI TAC,=10*JIFSEC ;WAIT 10 SECONDS
MOVEM TAC,BATYET ;BEFORE STARTING THE PHANTOM JOBS
SETZM ALFRED ;ZERO WAKEUP TIME FOR ALL PHANTOMS
MOVE TAC,[XWD ALFRED,ALFRED+1]
BLT TAC,ALFRED+BATLEN-1
>
IFKL10,< MOVEI TAC,KLUPT+424
MOVEM TAC,UUOLOC+P1PID
>;IFKL10
NOKL10,<
MOVE TAC,[JRST UUO1] ;SET UP PROCESSOR DATA STORAGE
MOVEM TAC,UUO0+1
MOVE TAC,[JRST UUO3]
MOVEM TAC,UUO2+1
MOVEI TAC,40
CONSZ APR,MAOFF
IORI TAC,100
MOVEM TAC,UUOLOC+P1PID
ADDI TAC,20 ;THE 60-TRAPS
MOVEM TAC,UU2LOC+P1PID
>;NOKL10
MOVE TAC,[JRST PIERR1]
MOVEM TAC,PIERR+1
MOVE TAC,[POINT 36,CIPWT-1,35]
MOVEM TAC,CLOCK
MOVEI TAC,CAT(CH,\APRCHN)
MOVEM TAC,APRCH+P1PID
MOVEI TAC,CAT(CH,\CLKCHN)
MOVEM TAC,CLKCH+P1PID
MOVE TAC,[P2PID]
MOVEM TAC,OTHERID+P1PID
MOVEI TAC,CLKSAVE
MOVEM TAC,CLKSV+P1PID
MOVEI TAC,CLKESAVE
MOVEM TAC,CLKESV+P1PID
MOVE TAC,[JEN @UUO0]
MOVEM TAC,UUOXIT
MOVEM TAC,UUOXI
MOVE PID,[P1PID]
MOVEM PID,APRID+P1PID
MOVE P,[IOWD ERRPLN,ERRPDL]
MOVEM P,ERRPD(PID)
MOVE TAC,[IOWD APRPLN,APRPD]
MOVEM TAC,APRPDL(PID)
SETOM JBTMSK
MOVE TAC,[JBTMSK,,JBTMSK+1]
BLT TAC,JBTMSK+JOBN-1
SETOM JBTWKM
MOVE TAC,[XWD JBTWKM,JBTWKM+1]
BLT TAC,JBTWKM+JOBN-1
;CORE IS INITIALIZED.
PUSHJ P,FSINIT ;AND FREE STORAGE SYSTEM
PUSHJ P,NXTINI ;INITIALIZE SCHEDULER FIRST
;SO DEVICES MAY RESET QUEUES IF DESIRED
IFN FTDISK,< PUSHJ P,FBINI >
PUSHJ P,SPWINI ;INITIALIZE SPACEWAR SERVICE
PUSHJ P,QINI ;INITIALIZE QUEUE STRUCTURE
PUSHJ P,DISINIT ;INITIALIZE DISASTER TYPEOUT SYSTEM.
PUSHJ P,MPXINI
SKIPE FBACT
JRST IOG0X
PUSHJ P,DISMES
ASCIZ /(3330 SWAPPER)
/
;HERE WE INITIALIZE ALL THE DEVICES IN THE DEVICE LIST
;NOTE THAT FREE STORAGE MUST BE SET UP
;ALSO NOTE THAT EACH DEVICE MUST CORRECTLY LINK TO
;THE NEXT BEFORE RETURNING
IOG0X: HLRZ DDB,DEVLST ;GO UP THE DEVICE LIST, DOING GOOD THINGS
SETZM SAVITM ;DSP OF LAST DEVICE
IOG0: HRRZ TAC,DEVSER(DDB) ;GET THE DEVICE SERVICE DISPATCH
CAMN TAC,SAVITM ;SAME AS LAST MEANS INITIALIZED ALREADY.
JRST IOG01 ;YES
MOVEM TAC,SAVITM ;SAVE THE DEVICE DISPATCH
PUSH P,DDB
PUSHJ P,DINI(TAC) ;INITIALIZE THE DEVICE
POP P,DDB
IOG01: MOVEI TAC,ASSPRG
ANDCAB TAC,DEVMOD(DDB) ;TURN OF ASSIGNED BY PROG BIT
HRLOI TAC1,77 ;MAKE MASK FOR MODE BITS AND HUNG COUNT
TDNE TAC,[TTYATC,,ASSCON] ;IF ASSIGNED BY CONSOLE THEN OR ATTACHED
TLO TAC1,770000 ;SAVE JOB NUMBER ALSO
ANDM TAC1,DEVCHR(DDB);GLONK!
TLNN TAC,DVTTY!DVLPT ;THESE GUYS ARE RIGHT(?)
SETZM DEVIOS(DDB)
SETZM DEVBUF(DDB)
HLRZ DDB,DEVSER(DDB) ;LINK ON MACDUFF
JUMPN DDB,IOG0 ;LOOP TO NEXT DEVICE
IFE FTNSWP,< ;OLD UDP SWAPPER
MOVEI TAC,ASSPRG!ASSCON
SKIPE DDB,SWPDDB ;IF SWAPPING ON THE UDP
IORM TAC,DEVMOD(DDB) ;MAKE SURE NO ONE CAN ATTACH/ASSIGN IT.
>
IFN FTSWAP,< PUSHJ P,SWPINI> ;INITIALIZE THE SWAPPER AFTER DEVICES
MOVE TAC,[RSTBEG,,RSTBEG+1]
BLT TAC,RSTEND-1
;NORMALIZE ALL JOB SLOTS.
;SINCE 200 RESTARTS HAVE BEEN FLUSHED, THIS CODE IS MUCH SIMPLER.
MOVEI J,JOBN-1
IOG2: MOVSI TAC,JERR
MOVEM TAC,JBTSTS(J)
SOJGE J,IOG2
SETZM JOB
;FORM INITIAL CHECKSUM.
MOVE TAC,[XWD CHKBEG-CHKEND,CHKBEG] ;AOBJN POINTER
MOVEM TAC,MONPTR
PUSHJ P,CHECK
MOVEM TAC1,MONSUM
IFN FTHSYS,<
MOVE TAC,[400000-HIEND,,400000] ;AOBJN POINTER TO HISYS
MOVEM TAC,HMNPTR
PUSHJ P,CHECK
MOVEM TAC1,HMNSUM
>
IFN FTSTAT, < MOVE TAC,[POINT 18,STATS]
MOVEM TAC,STATPTR >;INITIALIZE STATISTICS POINTER
XCT PICON ;PION, CH 3-7 AND PARITY ERROR ENABLE
IFKL10,<
MOVEI TAC,7740 ;ALL APR ERROR BITS
HRRM TAC,KLPARC ;ENABLE APR CONSZ
CONO APR,127760+APRCHN ;ENABLE EVERYTHING
>;IFKL10
REPEAT 0,< DATAO PTR,[1] ;ENABLE SYSTEM WR DETECTOR >
MOVEI TAC,[ASCIZ /SYSTEM STARTED ON /]
SKIPN INIMES ;LOAD OR INITIALIZE?
MOVEM TAC,INIMES ;NO, IT MUST BE A START
MOVSI J,-TCONLN-1 ;NO. OF TTY LINES(REAL ONES).
IOG3: SKIPN DDB,TTYTAB(J) ;GET DDB FOR NEXT TTY.
JRST IOG3A ;OOPS, NO DDB.
PUSHJ P,CRLF ;TYPE A CRLF
MOVE TAC1,DEVNAM(DDB)
PUSHJ P,PRNAME ;PRINT NAME OF CONSOLE
MOVEI TEM,11
XCT TYO ;TAB
MOVEI TAC,[ASCIZ/ (DOWN) /]
SKIPN MAINTMODE
SKIPE TTYLOK
PUSHJ P,CONMES ;TELL THEM THAT WE'RE DOWN
MOVE TAC,INIMES ;GET THE ADDRESS OF MESSAGE
PUSHJ P,CONMES ;SEND IT
PUSHJ P,DAYT2 ;TIME OF DAY
PUSHJ P,PRCNTC
PUSHJ P,TTYSTR ;START THE TTY TYPING
IOG3A: AOBJN J,IOG3 ;SEND MESSAGE TO ALL TTY'S.
IFN FTDDT,<
PUSHJ P,DISMES ;INCASE LOWCOR GETS CLOBBERED.
ASCIZ /DDT STARTS AT /
HRRZ TAC,SYSDSP+1
PUSHJ P,DISLOC
PUSHJ P,DISCRLF
>
; MOVE TAC,THSDAT ;APRIL 1 HACK.
; IDIVI TAC,=12*=31 ;DIVIDE TO GET YEARS IN TAC, DAY OF YEAR IN TAC1
; CAIN TAC1,=31*3 ;APRIL 1?
; SETOM AFOOL ;YES.
SETZM INIMES ;CLEAR FOR NEXT TIME
SETZB J,JOB ;INDICATE JOB ZERO
NOKL10,<
MOVE TAC,[JSR PAGINT] ;PAGER TRAP INSTRUCTION
MOVEM TAC,170 ;STORE FOR SYSTEM
>;NOKL10
MOVEI PID,P1PID ;INDICATE P1
JRST NULJOB ;START THE NULL JOB.
;SYIDDT - INITIALIZE SWAPPING/XCOR DDT.
LOSYS
IFN FTDDT,<
SYIDDT:
SETZM DDTFLG ;WE ARE NOT INSIDE OF DDT RIGHT NOW.
IFN FTDSWP,<
SKIPE NOTDDT
JRST SYIDD1
SETOM DDTSWP
IFN FTXCOR,<
SETOM DDTXCOR ;ASSUME BOTH, FIGURE OUT RIGHT ONE LATER
>;FTXCOR
>;FTDSWP
SYIDD1:
NOKL10,<DATAI APR,TAC ;READ THE DATA SWITCHES >;NOKL10
IFKL10,<PUSHJ P,RSWITCH ;READ SWITCHES >;IFKL10
TLC TAC,777 ;COMPLEMENT 9 BITS ON THE LEFT
TLNE TAC,-1 ;SKIP IF SWITCHES HAVE 777,, IN LH
JRST SYIDD3
TRNN TAC,2 ;DOES HE WANT NO DDT
JRST SYIDD2 ;SWITCHES DON'T SAY NO DDT
SETOM NOTDDT ;FLAG TO GET RID OF DDT
SETZM DDTSWP
SETZM DDTXCOR
MOVE TAC1,[HALT AUTOLOAD] ;MAKE A HALT
MOVEM TAC1,DDT ;AND PLANT IT ON TOP OF DDT
MOVEI TAC1,DDT+1 ;GET THE ADDRESS BEYOND DDT
MOVEM TAC1,SYSSIZ ;SAVE AS SYSSIZ
SETZM 36 ;NO SYMBOL TABLE POINTER
POPJ P, ;CONTINUE
SYIDD2:
IFN FTDSWP,<
TRNE TAC,4
SETZM DDTSWP ;DON'T SWAP ON THE LIBRASCOPE
IFN FTXCOR,<
TRNE TAC,10
SETZM DDTXCOR ;WANTS TO NOT SWAP DDT IN EXTRA CORE
>;FTXCOR
>;FTDSWP
SYIDD3:
IFN FTDSWP,<
SKIPN NOTDDT ;DOES HE WANT DDT?
PUSHJ P,DDTINI ;YES INITIALIZE SWAPPING OF DDT
>;FTDSWP
IFN FTHSYS,<
SKIPN DDTXCOR ;SKIP IF DDT IS IN HIGH CORE
TDZA TAC1,TAC1
HLRE TAC1,XDDPTR ;-NUMBER OF PAGES USED BY DDT AND SYMBOLS
MOVN TAC1,TAC1
ADDI TAC1,1000 ;FIRST PAGE FOR HISYS
MOVEM TAC1,FHIPAG
MOVEI TAC1,-1
MOVEM TAC1,37 ;INITIAL SYSTEM JOBREL FOR DDT
>
POPJ P,
>;FTDDT
; P2 INITIALIZE ROUTINE
↑P2INI: CONO APR,200000 ;RESET CPU
CONO PI,10400 ;CLEAR PI SYSTEM
SETZB J,P2DATA
MOVE TAC,[XWD P2DATA,P2DATA+1]
BLT TAC,P2DATA+PDATALEN-1
CONO APR,733550+APRCHN ;CLEAR EVERYTHING, ENABLE CLOCK INTS
MOVE P,[IOWD ERRPLN,ERRPDL+P2PID]
MOVE TAC,[JRST P2UUO1]
MOVEM TAC,UUO0+P2PID+1
MOVE TAC,[JRST P2UUO3]
MOVEM TAC,UUO2+P2PID+1
MOVE TAC,[JRST PIERR2]
MOVEM TAC,PIERR+P2PID+1
MOVEI TAC,40
CONSZ APR,MAOFF
IORI TAC,100
MOVEM TAC,UUOLOC+P2PID
ADDI TAC,20
MOVEM TAC,UU2LOC+P2PID ;FOR 60-TRAPS
MOVE TAC,[POINT 36,CIPWT+P2PID-1,35]
MOVEM TAC,CLOCK+P2PID
MOVEI TAC,CAT(P2CH,\APRCHN)
MOVEM TAC,APRCH+P2PID
MOVEI TAC,CAT(P2CH,\CLKCHN)
MOVEM TAC,CLKCH+P2PID
MOVE TAC,[P1PID]
MOVEM TAC,OTHERID+P2PID
MOVEI TAC,CL2SAVE
MOVEM TAC,CLKSV+P2PID
MOVEI TAC,CL2ESAVE
MOVEM TAC,CLKESV+P2PID
MOVE TAC,[JEN @UUO0+P2PID]
MOVEM TAC,UUOXIT+P2PID
MOVEM TAC,UUOXI+P2PID
SETZM JOB+P2PID
MOVEI PID,P2PID
MOVEM PID,APRID(PID)
MOVE TAC,[IOWD ERRPLN,ERRPDL+P2PID]
MOVEM TAC,ERRPD(PID)
MOVE TAC,[IOWD APRPLN,APRPD+P2PID]
MOVEM TAC,APRPDL(PID)
MOVE TAC,CH3
CAMN TAC,CH3 ; WAIT FOR P1 TO START TAKING CLOCK BREAKS
JRST .-1
XCT P2CON ; ENABLE PI, PARITY, ETC.
PUSHJ P,XGPIN2 ;INITIALIZE XGP FROM P2
PUSHJ P,PTRIN2 ;INITIALIZE PTR FROM P2
PUSHJ P,DISMES
IFLE PRCONF-1,<
ASCIZ/↓
PDP-6 STARTED / >;IFLE PRCONF-1
IFE PRCONF-2,<
ASCIZ/↓
KA10 STARTED / >;IFE PRCONF-2
PUSHJ P,DISDATE
JRST NULJOB
; POWER DOWN ROUTINES
NOKL10,<
↑PWROFF:
CONO PI,PIOFF ; NO MORE INTERRUPTS NOW
EXCH 17,PWRCNT ; AND COUNT DOWN
SOJG 17,. ;LOOP
MOVEI 17,-1 ; COUNT DONE, NO POWER DOWN AFTER ALL
EXCH 17,PWRCNT ;RESTORE 17
AOS P1OFF ;COUNT FAILURES
CONO PI,PION ;ENABLE INTERRUPTS
JEN @APRCHL
>;NOKL10
IFE PRCONF-2,<
↑P2ROFF:
CONO PI,PIOFF
EXCH 17,P2RCNT
SOJG 17,.
MOVEI 17,-1
EXCH 17,P2RCNT
AOS P2OFF ;COUNT FAILURES ON P2 ALSO
CONO PI,PION
JEN @AP2CHL
>;IF PRCONF=2
MCELTB: TTYLOK
MAINTM
DDOFF
IIIOFF
DEBMOD
EXPMOD ;SET TO MAKE LOGIN TYPE X.TXT[2,2]
NOLOGIN ;SET TO PREVENT LOGIN
IFN IMPSW,<IMPDIE;>0 ;NO IMP TODAY
IFN IMPSW,<IMPPMS;>0 ;SET TO ALLOW IMP TO COMPLAIN ON CTY
BLTSWP ;SET FOR BLT AFTER SWAPIN
IOPTEL ;PRINT EACH IOP EARLY RESPONSE AND DATA MISS
IFN FTSWPC,<SWPCHK;>0 ;CHECKSUM EVERY SWAP OP
IFN FTSWPC,<SWPCH2;>0 ;CHECKSUM EVERY SWAP OP AFTER SWAP OUT TOO
WRTPRO ;SET SOFTWARE WRITE PROTECT ON DISK
NMCELS←←.-MCELTB
BEND SYSINI
HISYS ;HIGH CORE